处理Asp中的错误

     处理Asp中的错误
  
  You just finished your ASP application in time, barely making the dealine! As you upload the final version to the webserver, you receive an email from your supervisor indicating that he's ready for your demo. You confidently stride into his office and give him instructions on aclearcase/" target="_blank" >ccesses the application through the Intranet.
  
  Your boss comes to the first page, and is asked to enter his name. You've created a slick, customized feel to the site, recording the user and his or her preferences in a database. Your boss types in his name, "The Pointy Haired Boss," and hits the submit button. Instead of being taken to the next page, he sees the following text pop up on the screen:
  
  Microsoft OLE DB Provider for ODBC Drivers error ' 80004005' [Microsoft][ODBC Access 97 ODBC driver Driver] syntax wrong near '
  
  Please note that I just made this error message up, so, please, no emails asking about how one gets this error by entering his name!
  
  You get one of those looks from your boss, a look that says, "I hope you weren't expecting a positive performance review."
  
  There's nothing worse to an end user than to see those dreaded ADO errors. They are misformatted, cryptic, and leave the user wondering what they are suppose to do. Your average end user doesn't know ODBC from OLE. So how can you prevent these nasty error messages?
  
  First you must insert at the top of your ASP page:
  
  
  <% On Error Resume Next %>
  This will tell ASP to just skip over any errors, instead of halting execution and printing out a nasty error message. You may be tempted to leave it at this, although if you do, and errors occur, your users won't be aware of them. They will think their information was correctly saved, when in actuality it wasn't due to an ADO error.
  
  What, then, do we want to do if there is an error? Well, the idea situation would be to let the end user know that an error had occurred and will be worked on, and automatically email technical support with the ADO error messages. So that is what we will do!
  
  The question now is how to we "trap" errors? Well, after any ADO call that accesses the database, we will want to put the following lines:
  
  
  
  If Err.number <> 0 then
   TrapError Err.description
  End If
  
  You will want to put this after all ADO calls that communicate directly with the database. This includes ConnectionObject.Open, ConnectionObject.Execute, and RecordsetObject.Open. Now, you may be wondering where the sub TrapError is defined: we're about to do that. Create a file called ErrorHandler.asp and put it in your /include or /scripts directory. In ErrorHandler.asp, we will have the following subs:
  
  
  TrapError
  ProcessErrors
  Let's look at the code for ErrorHandler.asp:
  
  
  
  <%
  Dim strErrorMessage
  Dim bolErrors
  
  'Initialize variables
  strErrorMessage = "" 'The error messages for tech. support
  bolErrors = False 'Have we found any errors yet?
  
  'Now our two subs
  sub TrapError(strError)
   bolErrors = True 'Egad, we've found an error!
  
   strErrorMessage = strErrorMessage & strError & ", "
  end sub
  
  
  
  'If there are any errors, this function will email tech. support
  sub ProcessErrors()
   if bolErrors then
   'Send the email
   Dim objCDO
   Set objCDO = Server.CreateObject("CDONTS.NewMail")
  
   objCDO.To = "techsupport@mysite.com"
   objCDO.From = "techsupport@mysite.com"
   objCDO.Subject = "AN ADO ERROR OCCURRED"
   objCDO.Body = "At " & Now & " the following errors occurred on " & _
   "the page " & Request.ServerVariables("SCRIPT_NAME") & _
   ": " & _
   chr(10) & chr(10) & strErrorMessage
  
   objCDO.Send
  
   Set objCDO = Nothing
  
   'Now, we've got to print out something for the user
   Response.Write "There has been a database error. Technical Support " & _
   "has already been notified. You will be informed when " & _
   "this issue is resolved. Thank you for your patience!"
   end if
  end sub
  
  That's all there is to it! Of course, you need to have the SMTP piece installed on your webserver. (See this article for more information on sending email using CDO.). Now, at the top of all your pages that you want to use the error handling routines, you'll need to include ErrorHandler.asp like so:
  
  <!--#include virtual="/include/ErrorHandler.asp"-->
  (See this article for more information on using includes.) You also need to make a call to the ProcessErrors sub at the end of all your ASP scripts which use this Error Trapping. So, the last line in the ASP file would be <% ProcessErrors %>. It is also imperative that you have On Error Resume Next at the top of all these pages as well!
  
  Well, hopefully that wasn't too difficult to follow! Error handling allows you to cope with error messages in a more pleasant way for the end user. Furthermore, it helps with debugging. User's accounts of errors are usually quite different than the actual error messages! With this approach, however, you're technical support department will receive the actual error messages! Neat, eh? (Oh yeah, one other benefit. I had implemented a system like this at my first internship. Folks would usually email me after an error occurred, but due to this email notification, I'd be to their office before they finished writing the email to me.)
  
  

原文转自：http://www.ltesting.net