根据模板文件建立动态目录树结构的类_自动测试脚本语言

根据模板文件建立动态目录树结构的类

发表于：2007-06-30来源：作者：点击数：标签：

根据模板文件建立动态目录树结构的类：建议入精华备查，有演示br 演示地址：http://www.cnaspol.com/myasp/mmtree/treesample.aspbr 本程序包括三文件和相关的图片文件，包括test.asp,tree.asp,mytree.txt组成br test.asp 引用类文件和模板文件br lt;%@ Langu

根据模板文件建立动态目录树结构的类：建议入精华备查，有演示 
演示地址：http://www.cnaspol.com/myasp/mmtree/treesample.asp 
本程序包括三文件和相关的图片文件，包括test.asp,tree.asp,mytree.txt组成 
test.asp 引用类文件和模板文件 
<%@ Language=VBScript %> 
 
<% 
@#======================================== 
@#BUILDING A TREE FROM A TEMPLATE FILE 
@#======================================== 
     
    Set MyTree1 = New Tree 
    MyTree1.Top = 10 
    MyTree1.Left = 10 
    MyTree1.ExpandImage = "plus.gif" 
    MyTree1.CollapseImage = "minus.gif" 
    MyTree1.LeafImage = "webpage.gif" 
 
    MyTree1.LoadTemplate Server.MapPath("mytree.txt") 
     
    MyTree1.Draw() 
     
    Set MyTree1 = Nothing 
 
%> 
 
</BODY> 
</HTML> 
 
 
mytree.txt 树形结构模板文件 
 
Cisco 
    Cisco Links #1 
        <A HREF="#">Adjusting IP MTU, TCP MSS, and PMTUD on Windows and Sun Systems (by Cisco)</A> 
        <A HREF="#">Cisco Command Documentation</A> 
        <A HREF="#">Cisco@#s Collection</A> 
    Cisco Links #2 
        <A HREF="#">DFW Cisco Users Group</A> 
        <A HREF="#">Internet Protocol Journal (by Cisco)</A> 
    asp #2 
        asp #2 
            <A HREF="#">vb</A> 
            <A HREF="#">asp</A> 
Desktop 
    Cisco Links #3 
        <A HREF="#">Area Code Lookup</A> 
        <A HREF="#">Arin Based Whois Search</A> 
        <A HREF="#">World Time Zone Map</A> 
    Cisco Links #4 
        <A HREF="#">Area Code Lookup</A> 
        <A HREF="#">Arin Based Whois Search</A> 
        <A HREF="#">World Time Zone Map</A> 
        <A HREF="#">World Time Zone Map</A> 
Internet 
    <A HREF="#">Index of Traceroute Web Servers</A> 
    <A HREF="#">Internet Health Report (Daze Networks, Inc.</A> 
    <A HREF="#">Internet Protocol Journal (by Cisco)</A> 
    <A HREF="#">Internet Traffic Report</A> 
    <A HREF="#">InterNIC Network Solutions Homepage</A> 
    <A HREF="#">IP 101: All About IP Addressing by CMP Net</A> 
Network 
    <A HREF="#">Digex Network Services Group</A> 
    <A HREF="#">Network Computing Online</A> 
    <A HREF="#">Network Computing Online: Technology Center</A> 
    <A HREF="#">Network Training Web Site (by InterOperability Lab)</A> 
    <A HREF="#">Networking Primer (by Bay Networks)</A> 
    <A HREF="#">Subnetting (by Network Computing Online)</A> 
Software Support 
    <A HREF="#">Symantec Security Alerts</A> 
Technology 
    <A HREF="#">Technology Dictionary (by PCWebopaedia)</A> 
    <A HREF="#">Technology Dictionary (by whatis?com)</A> 
    <A HREF="#">Technology Topics (by N.E.T.)</A> 
    <A HREF="#">Tracert</A> 
    <A HREF="#">Understanding I.P. Addressing (by 3Com)</A> 
Trading 
    <A HREF="#">Keynote Web Broker Trading Index</A>         
    <A HREF="#">NASDAQ</A> 
Training 
    <A HREF="#">RFC Index (Ohio State University)</A> 
    <A HREF="#">Vi/Ex Editor (by CMP Net)</A> 
 
 
 
 
tree.asp   处理树形结构的vbsclass类(关键) 
 
<% 
Dim gblTreeNodeCount:gblTreeNodeCount = 1 
Class TreeNode 
    Public Value 
    Public ExpandImage 
    Public CollapseImage 
    Public LeafImage 
    Public Expanded 
    Private mszName 
    Private mcolChildren 
    Private mbChildrenInitialized 
     
    Public Property Get ChildCount() 
        ChildCount = mcolChildren.Count 
    End Property 
     
    Private Sub Class_Initialize() 
        mszName = "node" & CStr(gblTreeNodeCount) 
        gblTreeNodeCount = gblTreeNodeCount + 1 
         
        mbChildrenInitialized = False 
        Expanded = False 
    End Sub 
 
    Private Sub Class_Terminate() 
        If mbChildrenInitialized And IsObject(mcolChildren) Then 
            mcolChildren.RemoveAll() 
            Set mcolChildren = Nothing 
        End If 
    End Sub 
     
    Private Sub InitChildList() 
        Set mcolChildren = Server.CreateObject("Scripting.Dictionary") 
        mbChildrenInitialized = True 
    End Sub 
     
    Private Sub LoadState() 
        If Request(mszName) = "1" Or Request("togglenode") = mszName Then 
            Expanded = True 
        End If 
    End Sub 
     
    Public Function CreateChild(szValue) 
         
        If Not mbChildrenInitialized Then InitChildList() 
         
        Set CreateChild = New TreeNode 
        CreateChild.Value = szValue 
        CreateChild.ExpandImage = ExpandImage 
        CreateChild.CollapseImage = CollapseImage 
        CreateChild.LeafImage = LeafImage 
     
        mcolChildren.Add mcolChildren.Count + 1, CreateChild 
         
    End Function 
     
    Public Sub Draw() 
     
        LoadState() 
 
        Response.Write "<table border=""0"">" & vbCrLf 
        Response.Write "<tr><td>" & vbCrLf 
         
        If Expanded Then 
            Response.Write "<a href=""javascript:collapseNode(@#" & mszName & "@#)""><img src=""" & CollapseImage & """ border=""0""></a>" & vbCrLf 
        ElseIf Not mbChildrenInitialized Then 
            Response.Write "<img src=""" & LeafImage & """ border=0>" & vbCrLf 
        Else 
            Response.Write "<a href=""javascript:expandNode(@#" & mszName & "@#)""><img src=""" & ExpandImage & """ border=""0""></a>" & vbCrLf 
        End If 
         
        Response.Write "</td>" & vbCrLf 
        Response.Write "<td>" & Value & "</td></tr>" & vbCrLf 
     
        If Expanded Then 
            Response.Write "<input type=""hidden"" name=""" & mszName & """ value=""1"">" & vbCrLf 
             
            If mbChildrenInitialized Then 
                Response.Write "<tr><td> </td>" & vbCrLf 
                Response.Write "<td>" & vbCrLf 
 
                For Each ChildNode In mcolChildren.Items 
                    ChildNode.Draw() 
                Next 
 
                Response.Write "</td>" & vbCrLf 
                Response.Write "</tr>" & vbCrLf 
            End If 
        End If 
         
        Response.Write "</table>" & vbCrLf 
         
    End Sub 
         
End Class 
 
 
Class Tree 
     
    Public Top 
    Public Left 
    Public ExpandImage 
    Public CollapseImage 
    Public LeafImage 
    Private mszPosition 
    Private mcolChildren 
     
    Public Property Let Absolute(bData) 
        If bData Then mszPosition = "absolute" Else mszPosition = "relative" 
    End Property 
     
    Public Property Get Absolute() 
        Absolute = CBool(mszPosition = "absolute") 
    End Property 
     
    Private Sub Class_Initialize() 
        Set mcolChildren = Server.CreateObject("Scripting.Dictionary") 
        mnTop  = 0 
        mnLeft = 0 
        mszPosition = "absolute" 
    End Sub 
 
    Private Sub Class_Terminate() 
        mcolChildren.RemoveAll() 
        Set mcolChildren = Nothing 
    End Sub 
 
    Public Function CreateChild(szValue) 
         
        Set CreateChild = New TreeNode 
 
        CreateChild.Value = szValue 
        CreateChild.ExpandImage = ExpandImage 
        CreateChild.CollapseImage = CollapseImage 
        CreateChild.LeafImage = LeafImage 
     
        mcolChildren.Add mcolChildren.Count + 1, CreateChild 
     
    End Function 
 
    Public Sub LoadTemplate(szFileName) 
        Dim objWorkingNode 
        Dim colNodeStack 
        Dim fsObj, tsObj 
        Dim szLine 
        Dim nCurrDepth, nNextDepth 
         
        Set colNodeStack = Server.CreateObject("Scripting.Dictionary") 
        Set fsObj = CreateObject("Scripting.FileSystemObject") 
        Set tsObj = fsObj.OpenTextFile(szFileName, 1) 
         
        nCurrDepth = 0 
        While Not tsObj.AtEndOfLine 
            nNextDepth = 1 
            szLine = tsObj.ReadLine() 
             
            If nCurrDepth = 0 Then 
                Set objWorkingNode = CreateChild(Trim(szLine)) 
                nCurrDepth = 1 
            Else 
                While Mid(szLine,nNextDepth,1) = vbTab Or Mid(szLine,nNextDepth,1) = " " 
                    nNextDepth = nNextDepth + 1 
                WEnd 
         
                If nNextDepth > 1 Then szLine = Trim(Mid(szLine,nNextDepth)) 
                 
                If szLine <> "" Then 
                    If nNextDepth > nCurrDepth Then 
                        If colNodeStack.Exists(nCurrDepth) Then 
                            Set colNodeStack.Item(nCurrDepth) = objWorkingNode 
                        Else 
                            colNodeStack.Add nCurrDepth, objWorkingNode 
                        End If 
                         
                        Set objWorkingNode = objWorkingNode.CreateChild(szLine) 
                                     
                        nCurrDepth = nCurrDepth + 1 
                    ElseIf nNextDepth <= nCurrDepth Then 
                         
                        If nNextDepth > 1 Then 
                             
                            nNextDepth = nNextDepth - 1 
                            While Not colNodeStack.Exists(nNextDepth) And nNextDepth > 1 
                                nNextDepth = nNextDepth - 1 
                            WEnd 
                         
                            Set objWorkingNode = colNodeStack.Item(nNextDepth) 
                            Set objWorkingNode = objWorkingNode.CreateChild(szLine) 
                             
                            nNextDepth = nNextDepth + 1 
                        Else 
                            Set objWorkingNode = CreateChild(szLine) 
                        End If 
                         
                        nCurrDepth = nNextDepth 
                    End If 
                End If 
                 
            End If 
        WEnd 
 
        tsObj.Close() 
        Set tsObj = Nothing         
        Set fsObj = Nothing 
         
        colNodeStack.RemoveAll() 
        Set colNodeStack = Nothing 
             
    End Sub 
 
 
    Public Sub Draw() 
         
        AddClientScript() 
         
        Response.Write "<div id=""treectrl"" style=""left: " & Left & "px; top: " & Top & "px; position: " & mszPosition & ";"">" & vbCrLf 
        Response.Write "<form name=""treectrlfrm"" action=""" & Request.ServerVariables("SCRIPT_NAME") & """ method=""get"">" & vbCrLf 
        Response.Write "<table border=""0"">" & vbCrLf 
        Response.Write "<tr><td>" & vbCrLf 
 
        For Each ChildNode In mcolChildren.Items 
            ChildNode.Draw() 
        Next 
 
        Response.Write "</td></tr>" & vbCrLf 
        Response.Write "</table>" & vbCrLf 
 
        Response.Write "<input type=""hidden"" name=""togglenode"" value="""">" & vbCrLf 
        Response.Write "</form>" & vbCrLf 
        Response.Write "</div>" & vbCrLf 
 
    End Sub 
 
    Private Sub AddClientScript() 
    %> 
        <script language="JavaScript"> 
         
        function expandNode(szNodeName) 
        { 
            if(document.layers != null) { 
                document.treectrl.document.treectrlfrm.togglenode.value = szNodeName; 
                document.treectrl.document.treectrlfrm.submit(); 
            } 
            else { 
                document.all["treectrlfrm"].togglenode.value = szNodeName; 
                document.all["treectrlfrm"].submit(); 
            } 
        } 
         
        function collapseNode(szNodeName) 
        { 
            if(document.layers != null) { 
                document.treectrl.document.treectrlfrm.elements[szNodeName].value = -1; 
                document.treectrl.document.treectrlfrm.submit(); 
            } 
            else { 
                document.treectrlfrm.elements[szNodeName].value = -1; 
                document.treectrlfrm.submit(); 
            } 
        } 
         
        </script> 
    <%     
    End Sub 
 
End Class 
%>

原文转自：http://www.ltesting.net

软件测试 > 测试开发技术 > 软件测试开发语言 > 自动测试脚本语言 >