关于释放session的两篇文章（二）

Deleting a Subset of Session Variables

When using Sessions to store variables in, I use a naming convention - for example, for all Customer related info I prefix the session variable with the substring Customer. (so for the CustomerID it would be Customer.ID, the customer username would be Customer.Name, etc.) This is very useful when viewing the session objects as you can see the related objects straight off.

The problem I had the other day was that I wanted to remove only those items from the Session which were prefixed SW.. So first off I used the following code:

‘’---------------------------------------
Session("SW.1")="Test 1"
Session("SW.2")="Test 2"
Session("Other")="Other"

For Each SessionItem in Session.Contents
  If Left(SessionItem,3) = "SW." then
    Session.Contents.Remove(SessionItem)
  end if
Next
‘’---------------------------------------

This seems fine, but when it‘’s run, what happens is that SW.1 is removed, but SW.2 is NOT removed. Why? I‘’m not exactly sure, but I guess that the index is then reset so that SW.2 is now where SW.1 was, and seeing as we have iterated past that item in the For Each...Next statement, the loop just moves to Other, missing out SW.2 altogether! Eek!

So to get round this I wrote the following function, which will properly delete all Session variables that begin with a specified substring:

‘’---------------------------------------
function SessionRemoveSelected(sItemPrefix)
‘’/////////////////////////////////////////////////
‘’ Remove Selected Items starting with sItemPrefix
‘’ from the Session. e.g. SS. will remove SS.ID and
‘’ SS.NAME but not CustomerID Returns True or False
‘’ depending on whether any items where removed.
‘’---------------------------------------
‘’ sItemPrefix [string] : Item Prefix
‘’/////////////////////////////////////////////////
  dim arySession()
  dim lCount, lPrefixLength
  dim SessionItem
  dim blnResult
    
  lCount = -1
  lPrefixLength = len(sItemPrefix)
  blnResult = false
    
  ‘’ temporarily store in array items to remove
  For Each SessionItem in Session.Contents
    if left(SessionItem,lPrefixLength) = sItemPrefix then
      lCount = lCount + 1
      redim preserve arySession(lCount)
      arySession(lCount) = SessionItem
    end if
  Next

  ‘’ remove items
  if IsArray(arySession)and lCount >= 0 then
    for lCount = LBound(arySession) to UBound(arySession)
      Session.Contents.Remove(arySession(lCount))
    next
    blnResult=true
  end if

  SessionRemoveSelected = blnResult
end function
‘’-------------------------------------------------

原文转自：http://www.ltesting.net