AutoRedraw属性与窗体设备场景的深入探讨

大家知道AutoRedraw是设置窗体是否重画的。那为什么为false窗体上的图形就不会被重画，而为true则窗体在被覆盖后再显示，窗体上的图形仍旧在？

这个问题其实与窗体的设备场景有直接的关系。即使没接触过Windows GDI开发的朋友也一定听说过设备场景（Device Context），设备场景是用来控制窗体图形显示方式的对象。比如，我们可以通过设置设备场景的画笔对象来控制在窗体上的线条的颜色、粗细，设置区域对象来控制窗体的外形，比如说将窗体变成五角形，星形，甚至任何乱七八糟的形状，可以设置剪切区并加一点代码就可以将窗体变成透明的，或者通过CBitmap对象来截获窗体的图象——而我们今天讨论的是如何在AutoRedraw属性的两种设置下返回我们所需的设备场景句柄。

窗体有这么几个属性需要复习一下：hDC——窗体的设备场景；窗体image对象的Handle属性——窗体前景画面图像的句柄；窗体picture对象的Handle属性——窗体背景图像的句柄。当我们将窗体的AutoRedraw属性设置为true时，窗体的设备场景其实存在两个。这可以以以下代码证实：



Private Sub Form_Click()



Dim lDC As Long

lDC = GetDC(Me.hwnd)   ‘GetDC是一个API函数，它返回某窗体的设备场景。请用API Text Viewer加入该函数的声明

Print Me.hDC

Print lDC



End Sub

（注意当窗体的AutoRedraw属性为true时窗体的Paint事件不会被激发。）



在窗体上输出的数字中我们清析地看到，这两个句柄是不同的。其中，窗体的hDC属性是窗体的一个内存设备场景句柄。对于窗体的任何绘图（例如画一条线，一个圆圈等）工作都会写入该内存设备场景。每当该窗体接收到一个Paint事件时，它就用该内存设备场景刷新窗体。所以当我们重新显示窗体的时候，它始终能重画窗体上所有的图形。而我们用GetDC函数返回的设备场景句柄则是真正意义上的窗体句柄，当前窗体显示什么图形，那么该设备场景的CBitmap对象保存的就是该图形。比如说，我们画了一个圆圈，又用别的窗体将它掩盖了一半，我们又用GetDC返回的句柄截获窗体的图片，那么该图片中只有一半的圆圈。

当AutoRedraw属性为false的时候，窗体的内存设备场景就不存在了。由于没有了保存窗体图像信息的内存设备场景，所以窗体就无法确定重显时如何重画窗体，因而就不会去重画被覆盖掉又重显的内容。用GetDC函数和窗体的hDC属性返回的句柄是相同的，它们都是窗体真正意义上的设备场景句柄。

以下语句可以截取窗体的图像，大家可以在AutoRedraw属性为不同的时候截获这几种可能的窗体图片以比较一下。（请先在窗体上画一个PictureBox，取名为picSave，并将其Visible属性设为false，AutoRedraw属性设为true。再将窗体及图像框的ScaleMode设为3。运行该程序前请先检查PictureBox的hDC是否存在，小弟在几台机子上发现即使设置了HasDC属性仍无法获得该hDC的情况。）

如小弟有错误之处欢迎来信探讨：sproll@163.com

Option Explicit

Private Declare Function GetDC Lib "user32" (ByVal hwnd As Long) As Long

Private Declare Function DeleteDC Lib "gdi32" (ByVal hdc As Long) As Long

Private Declare Function CreateCompatibleDC Lib "gdi32" (ByVal hdc As Long) As Long

Private Declare Function CreateCompatibleBitmap Lib "gdi32" (ByVal hdc As Long, ByVal nWidth As Long, ByVal nHeight As Long) As Long

Private Declare Function SelectObject Lib "gdi32" (ByVal hdc As Long, ByVal hObject As Long) As Long

Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long

Private Declare Function BitBlt Lib "gdi32" (ByVal hDestDC As Long, ByVal X As Long, _

ByVal Y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, _

ByVal xSrc As Long, ByVal ySrc As Long, ByVal dwRop As Long) As Long

Private Const SRCCOPY = &HCC0020



Private Sub Form_Click()



Dim lReturn As Long



Dim lDC As Long

Dim lBitmap As Long

Dim lOldBitmap As Long



lDC = CreateCompatibleDC(frmAutoRedraw.PicSave.hdc) '创建与PictureBox的设备场景兼容的一内存设备场景

lBitmap = CreateCompatibleBitmap(frmAutoRedraw.hdc, frmAutoRedraw.ScaleWidth, frmAutoRedraw.ScaleHeight) '创建与窗体设备场景的CBitmap对象兼容的CBitmap对象

lOldBitmap = SelectObject(lDC, lBitmap) '将创建的新Cbitmap对象选入内存设备场景，并保存原CBitmap对象。

lReturn = BitBlt(lDC, 0, 0, frmAutoRedraw.ScaleWidth, frmAutoRedraw.ScaleHeight, frmAutoRedraw.hdc, 0, 0, SRCCOPY) '将窗体上显示的图样拷贝到内存设备场景

lReturn = BitBlt(frmAutoRedraw.PicSave.hdc, 0, 0, frmAutoRedraw.ScaleWidth, frmAutoRedraw.ScaleHeight, lDC, 0, 0, SRCCOPY) '将内存设备场景的图样拷贝到PictureBox的设备场景中

SavePicture frmAutoRedraw.PicSave.Image, "c:\My documents\form.bmp" '保存PictureBox的图样

lBitmap = SelectObject(lDC, lOldBitmap) '将内存设备场景的原CBitmap对象选回内存设备场景

lReturn = DeleteObject(lBitmap) '删除创建的CBitmap对象

lReturn = DeleteDC(lDC) '删除内存设备场景



End Sub



Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)



If Button = vbRightButton Then

  frmAutoRedraw.Line (0, 0)-(150, 150)

End If



End Sub



Private Sub Form_Resize()



PicSave.Width = Me.ScaleWidth

PicSave.Height = Me.ScaleHeight



End Sub

原文转自：http://www.ltesting.net