SocketProgrammingwithVB

 Socket Programming with VB

我们在烟台项目的网络传输部分研究中涉及到了Winsock编程，经过较长时间的学习，做出了几个模型。本文是我在工作过程中的一些体会，不足之处请大家指正。

1． 简介
在Windows下的各种网络编程接口中，Windows Sockets脱颖而出，这是因为indows Sockets规范是一套开放的、支持多种协议的Windows下的网络编程接口。利用 WinSock 控件可以与远程计算机建立连接，并通过用户数据文报协议 (UDP)或者传输控制协议 (TCP)进行数据交换。这两种协议都可以用来创建客户与服务器应用程序。
Windows Sockets规范是建立在Beckley套接口模型上的， 这个模型现在已是TCP/IP网络的标准，所谓套接口就是指通信的一端。套接口通常和同一个域中的套接口交换数据（数据交换也可能穿越域的界限，但这时一定要执行某种解释程序）。目前可以使用两种套接口，即流套接口和数据报套接口。流套接口提供了双向的，有序的，无重复并且无记录边界的数据流服务。数据报套接口支持双向的数据流，但并不保证是可靠，有序，无重复的。我们在编程中只用到了流式套接口，无序的、可靠性较低的数据报套接口不能满足系统对准确高效数据传输的要求。

2． 客户机\服务器模型
一个在建立分布式应用时最常用的范例便是客户机/服务器模型。在这种方案中客户应用程序向服务器程序请求服务，服务器程序请求服务响应客户端的请求。通信的基石是套接口，所有的请求、响应工作都是由套接口完成的。

3． 套接口网络编程原理
流式套接口定义了一种可靠的面向连接的服务，实现了无差错无重复的顺序数据传输。
使用面向连接的套接口编程，其流程可由下图表示：

服务器Socket 客户端Socket4． Peer- to- Peer 通信程序 现在做一个具体的程序。这个程序是用VB写的，因为VB把Socket做成了控件，使用起来非常方便。这是一个点到点通信程序，功能是通信双方双工传送字符串。这个程序屏蔽了一个事实，及C\S模型，但在程序运行时必须先启动服务器。

服务器端：
建立一个新的工程，把Microsoft Winsock Control 控件加进来，如下图放置控件，主要就五个：两个文本框用于显示收到数据以及输入发送数据；一个CommandBotton于发送数据；一个小图标显示是否联接(联接了就显示出来visible=True)；最主要的是Winsock控件，所有的事都是它干的，而且从不显示出来（默默无闻）。
下面是代码，注释的较为清楚：
Option Explicit
Dim IsConnectionOpen As Boolean 

Private Sub Command1_Click()
If IsConnectionOpen = False Then
MsgBox "未建立联接!" '如果未建立连接，就弹出这么一个对话框
Else
Winsock1.SendData Text2.Text
'Socket就这么把数据发出去了，很简单
End If
End Sub

Private Sub Form_Load()
Winsock1.LocalPort = 1111
Winsock1.Listen 'Socket在程序启动时监听端口1111
Image1.Visible = False
IsConnectionOpen = False '开始状态为未联接
End Sub

Private Sub Winsock1_Close() '对方Socket关闭触发这个事件
Winsock1.Close '关闭自己
End '那也就把程序关了吧
End Sub

Private Sub Winsock1_ConnectionRequest(ByVal requestID As Long) '接收到对方联接 
'请求触发这个事件
If Winsock1.State <> sckClosed Then Winsock1.Close '使Socket在接收
'联接请求之前保持关闭状态

Winsock1.Aclearcase/" target="_blank" >ccept requestID 'Winsock1自己接收联接请求，与客户端Socket
'建立联接
IsConnectionOpen = True
Image1.Visible = True '现在联接好了
End Sub

Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)'收到数据触发这个事件
Dim str As String

Winsock1.GetData str '收到数据时，Winsock1把数据写入缓存str
Text1.Text = Text1.Text + str + Chr (13) + Chr (10)
Text1.SelStart = Len (Text1.Text)
'在文本框中显示接收的数据
End Sub


客户端：
同样也建立一个新的工程，把Winsock控件加进来。布局如下，比服务器稍微复
杂，因为客户端发出联接请求，因此多出两个文本框用于输入服务器的地址及端口给
Winsock控件，一个CommandBotton用于联接：


代码：
Option Explicit
Dim IsConnectionOpen As Boolean

Private Sub Command1_Click() '联接按钮
Winsock1.RemoteHost = Text1.Text
Winsock1.RemotePort = CLng(Text2.Text) '填好Socket的对方地址
'及对方端口号
Winsock1.Connect 'Socket发送联接请求，当联接成功时出发Winsock的
'Connect事件(看下边)
End Sub

Private Sub Command2_Click() '发送按钮
If IsConnectionOpen = False Then
MsgBox "未建立联接!"
Else
Winsock1.SendData Text3.Text
End If '同服务器端一样
End Sub

Private Sub Form_Load()
Text1.Text = "sjn"
Text2.Text = "1111" '程序启动时两个文本框先显示服务器的地址
'及端口号，无所谓，反正可以修改
Image1.Visible = False
IsConnectionOpen = False '一开始未联接
End Sub

Private Sub Winsock1_Close()
Winsock1.Close
End '同服务器端一样
End Sub

Private Sub Winsock1_Connect() '联接成功时触发
IsConnectionOpen = True
Image1.Visible = True '联接成功了
End Sub

Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
Dim str As String

Winsock1.GetData str
Text4.Text = Text4.Text + str + Chr(13) + Chr(10)
Text4.SelStart = Len(Text4.Text) '同服务器端一样
End Sub


至此，服务器与客户端均建立了。
运行时，服务器与客户端可分别放在两台机器上，也可以反放在一台机器上，无所谓。
先启动服务器，再运行客户端，现在你就可以胡说八道了。

两个程序的流程：（其实前面的图表已显示了，但有必要再罗嗦一下）

服务器： 
户端：

K，现在咱们已经建好了一个简单的C\S通信模型，确实很简单吧。再进一步，我们还可以加入很多功能，例如，通过 .Accept 方法，以及把Winsock控件做成数组，服务器可以与多个客户端建立连接，实现一个简单的聊天室。
关于Winsock控件：
1． 客户端的Socket必须准确填写双方约定的服务器的地址及监听端口，否则，它可不知道可设进行联接。
2． 双方通信是由Socket通信实体完成的，协议一般采用TCP协议，以保证准确的传输。
3． 具体的事件和方法见 程序及MSDN->目录->Visual Basic文档->使用VB->部件工具指南->使用ActiveX控件->使用Winsock控件 (里面写的相当详细)

原文转自：http://www.ltesting.net