图一：一个自定义窗体样式的例子

Region的基本原理

创建一个高科技的窗体的秘密是一个叫做Region的技术。一个Region就是计算机显示器的一个区域。Windows应用程序用Region在屏幕上绘制输出和执行点击测试（测试光标的位置）。简单来说，一个Region就是几个特定的输入输出能够在显示器上发生的区域。GDI

构造了三种可用的Region：矩形、椭圆形和多边形。API调用用于创建和操纵Region。

所以在VB窗体里需要做什么呢？很简单，每一个窗体都是在Region里边被绘制出的。事实上，每一个窗口都是在Region里被绘制的。你可能知道，windows操作系统定义了一个窗口作为一个区域，该区域接收该应用程序的输入，并且显示输出。听起来非常类似于定义一个Region。事实上，窗口是比Region复杂得多的。窗口可以呈现多种外观：窗体、按钮、文本框等等。然而总的来说，窗口被绘制在一个Region里边。所以我们可以说，每一个窗口拥有一个Region，所以VB窗体拥有一个Region。

通常情况下，一个窗体被绘制在一个矩形的Region里。事实上，VB帮助里边基本不谈论Region。操作系统自动为每一个窗体分派一个矩形Region。VB并不提示你去改变这些。因此，在设计模式里，你必须经常以矩形窗体工作。但是在少许简单的API的帮助下，你可以在运行的时候改变个窗体的Region。

以圆形运行

让我们看看最简单的二者选其一的Region，一个椭圆。Windows操作系统提供了一个函数CreateEllipticRgn，该函数提供一个矩形的左上角和右下角坐标。该函数记下了一个在此矩形里边的一个椭圆，用来创建需要的Region。

一旦你得到这个Region的句柄，你要把它指派到你的窗体里。为此，用CreateEllipticRgn函数，该函数把句柄提供给窗口和Region，还要提供一个布尔型的声明，用以确定当分派

Region后窗口是否重绘。通常情况下，你想把最后一个声明设为TRUE，下面是这些代码：

Public Declare Function CreateEllipticRgn _
               Lib "gdi32" (ByVal X1 As Long, _
                            ByVal Y1 As Long, _
                            ByVal X2 As Long, _
                            ByVal Y2 As Long) As Long

Public Declare Function SetWindowRgn _
               Lib "user32" (ByVal hWnd As Long, _
                             ByVal hRgn As Long, _
                             ByVal bRedraw As Boolean) As Long

Public Sub CreateEllipseFromWindow(ByRef oWindow As Object)
    Dim lRight As Long
    Dim lBottom As Long
    Dim hRgn As Long

    With oWindow
        lRight = .Width / Screen.TwipsPerPixelX
        lBottom = .Height / Screen.TwipsPerPixelY
        hRgn = CreateEllipticRgn(0, 0, lRight, lBottom)
        SetWindowRgn .hWnd, hRgn, True
    End With
End Sub

Private Sub Form_Load()
    CreateEllipseFromWindow Me
End Sub

应当注意到在这些代码中，要用到左上角和右下角的坐标作为椭圆的基础。当工程启动以后，该窗体最初有我们在设计的时候给定的尺寸，所以椭圆要基于那些数据。同时要注意，为了得到正确的尺寸，我们需要把高度和宽度从缇转换到像素。缺省状态下，VB用缇作为屏幕的尺寸。当用到Region时，需要以像素记数。Screen.TwipsPerPixelX和Screen.TwipsPerPixelY函数使得该转换容易进行。

当你运行这些代码时，你会发现该窗体的确以椭圆方式出现，但是是一个非常难看的椭圆。（图二）问题出在VB的窗体基于矩形的Region上面。然而窗体是不允许绘制在椭圆Region的外面的。所以结果是，矩形的角被严格的切掉了！你肯定不想做一个像这样的窗体的！