oracle中使用ANYDATA列对数据串行化方法

　　Oracle版本9提供了一种有趣的新的数据类型，开发人员借助此类型可以声明包括任何类型数据的变量。对于单个数据来说，此数据类型即ANYDATA。对于TABLE或者VARRAY数据来说，则为ANYDATASET。ANYTYPE用于描述存储在ANYDATA或者ANYDATASET变量以及栏中的数据类型。这些数据类型对于处理存储在数据库中的XML数据或高级序列（Advanced Queues）具有非常重要的意义。说明文档中提到了ANYDATA数据类型可以用于对对象进行串行化（serialize），但与之相关的示例较少。
　　
　　串行化首先将数据值和其他结构（structure）组成为另外一些结构，然后将生成的结构的所有构成成分输出为流。流可以被结构返回读取，并且将覆盖前一个会话的信息。通常而言，在应用程序中进行的保存和打开文件的操作即不过是串行化的一种形式。
　　
　　一个Oracle数据库或许需要使用串行化功能来存储一些表格数据的某个版本备份，这样可以在不使用数据库提交（commits）、回滚（rollbacks）、回闪（flashback）查询的情况下对数据进行查看和其他操作。许多应用程序都会用到类似的对数据源的控制功能，诸如可以在应用级对当前和以前的数据版本进行比较，或对合并操作（merge）和撤销操作（undo）所产生数据改变进行比较。很多此类应用程序都被设计为对每个表格创建一个备份表格。而对于数据库性能和开发进度来说，要维护这些众多的备份表格以及之间的各种关系，成为了生产数据（production data）以外的沉重负担。
　　
　　而通过ANYDATA数据类型以及动态SQL功能，使得通过单一的串行化存储进程来把许多需要备份的表格串行输入到一个单独的备份表格成为可能。ANYDATA的一个优势在于，不同于类似VARCHAR2的简单的转换数据类型，使用ANYDATA方法原始的数据类型并不会丢失。数据可以被存储在ANYDATA栏或者变量中而不会丢失任何细节（或根据在DATA和VARCHAR2之间进行转换的当前NLS语义而定）。这些存储的数据在转化过程中不会有任何损失。
　　
　　一个ANYDATA对象可以通过使用任何Convert*方法构造简单值的方法来实现，或者通过“piecewise”构造方法创建诸如对象和数据库一类的更为复杂的变量。对于本例而言，我将集中解释如何使用Convert*方法。
　　
　　为了创建一个串行化进程，我使用了动态SQL来产生一个对表格中所有数据的查询命令，其中包括ROWID。然后我将查询命令进行分解并描述，从而得到一个关于栏和数据类型的列表。再定义提取（fetch）出栏，将每一栏从各行中提取出来，然后将其插入到串行化表格中。在本例中我使用了DBMS_SQL，因为“自身动态SQL（native dynamic SQL）”现在还不能支持描述动态查询。绝大多数的工作都是对从DBMS_SQL数据类型代码到合适的数据类型方法以及函数的转换过程进行处理。要得到这些代码的列表，可以查看OCI包含文件ocidfn.h，或者是诸如USER_TAB_COLUMNS这样的对查看（view）的定义。在本例中，我使用了简单的数据类型（可以在EMP和DEPT表格中找到），这样可以直接对其进行转换。
　　
　　drop table serialized_data;
　　
　　create table serialized_data
　　
　　(
　　
　　　　tablename varchar2(30) not null,
　　
　　　　row_id rowid not null,
　　
　　　　colseq integer not null,
　　
　　　　item anydata
　　
　　);
　　
　　create or replace procedure serialize(p_tablename varchar2)
　　
　　is
　　
　　　　l_tablename varchar2(30) := upper(p_tablename);
　　
　　　　c　　　　　 pls_integer;　　　　-- cursor
　　
　　　　x　　　　　 pls_integer;　　　　-- dummy
　　
　　　　col_cnt　　 pls_integer;
　　
　　　　dtab　　　　dbms_sql.desc_tab;
　　
　　　　l_rowid　　 char(18);
　　
　　　　l_anydata　 anydata;
　　
　　　　l_vc2　　　 varchar2(32767);
　　
　　　　l_number　　number;
　　
　　　　l_vc　　　　varchar(32767);
　　
　　　　l_date　　　date;
　　
　　　　l_raw　　　 raw(32767);
　　
　　　　l_ch　　　　char;
　　
　　　　l_clob　　　clob;
　　
　　　　l_blob　　　blob;
　　
　　　　l_bfile　　 bfile;
　　
　　begin
　　
　　　　c := dbms_sql.open_cursor;
　　
　　　　dbms_sql.parse(c,'select rowid,'||p_tablename||'.* from '||p_tablename,
　　
　　　　　　dbms_sql.native);
　　
　　　　dbms_sql.describe_columns(c,col_cnt,dtab);
　　
　　　　dbms_sql.define_column(c,1,l_rowid,18);
　　
　　　　for i in 2 .. col_cnt loop
　　
　　　　　　case dtab(i).col_type
　　
　　　　　　when 1 then
　　
　　　　　　　　dbms_sql.define_column(c,i,l_vc2,dtab(i).col_max_len);
　　
　　　　　　when 2 then
　　
　　　　　　　　dbms_sql.define_column(c,i,l_number);
　　
　　　　　　when 9 then
　　
　　　　　　　　dbms_sql.define_column(c,i,l_vc,dtab(i).col_max_len);
　　
　　　　　　when 12 then
　　
　　　　　　　　dbms_sql.define_column(c,i,l_date);
　　
　　　　　　when 23 then
　　
　　　　　　　　dbms_sql.define_column_raw(c,i,l_raw,dtab(i).col_max_len);
　　
　　　　　　when 96 then
　　
　　　　　　　　dbms_sql.define_column_char(c,i,l_ch,dtab(i).col_max_len);
　　
　　　　　　when 112 then
　　
　　　　　　　　dbms_sql.define_column(c,i,l_clob);
　　
　　　　　　when 113 then
　　
　　　　　　　　dbms_sql.define_column(c,i,l_blob);
　　
　　　　　　when 114 then
　　
　　　　　　　　dbms_sql.define_column(c,i,l_bfile);
　　
　　　　　　end case;
　　
　　　　end loop;
　　
　　　　x := dbms_sql.execute(c);
　　
　　　　while dbms_sql.fetch_rows(c) != 0 loop
　　
　　　　　　dbms_sql.column_value(c,1,l_rowid);
　　
　　　　　　for i in 2 .. col_cnt loop
　　
　　　　　　　　case dtab(i).col_type
　　
　　　　　　　　when 1 then
　　
　　　　　　　　　　dbms_sql.column_value(c,i,l_vc2);
　　
　　　　　　　　　　l_anydata := ANYDATA.ConvertVarchar2(l_vc2);
　　
　　　　　　　　when 2 then
　　
　　　　　　　　　　dbms_sql.column_value(c,i,l_number);
　　
　　　　　　　　　　l_anydata := ANYDATA.ConvertNumber(l_number);
　　
　　　　　　　　when 9 then
　　
　　　　　　　　　　dbms_sql.column_value(c,i,l_vc);
　　
　　　　　　　　　　l_anydata := ANYDATA.ConvertVarchar(l_vc);
　　
　　　　　　　　when 12 then
　　
　　　　　　　　　　dbms_sql.column_value(c,i,l_date);
　　
　　　　　　　　　　l_anydata := ANYDATA.ConvertDate(l_date);
　　
　　　　　　　　when 23 then
　　
　　　　　　　　　　dbms_sql.column_value(c,i,l_raw);
　　
　　　　　　　　　　l_anydata := ANYDATA.ConvertRaw(l_raw);
　　
　　　　　　　　when 96 then
　　
　　　　　　　　　　dbms_sql.column_value(c,i,l_ch);
　　
　　　　　　　　　　l_anydata := ANYDATA.ConvertChar(l_ch);
　　
　　　　　　　　when 112 then
　　
　　　　　　　　　　dbms_sql.column_value(c,i,l_clob);
　　
　　　　　　　　　　l_anydata := ANYDATA.ConvertClob(l_clob);
　　
　　　　　　　　when 113 then
　　
　　　　　　　　　　dbms_sql.column_value(c,i,l_blob);
　　
　　　　　　　　　　l_anydata := ANYDATA.ConvertBlob(l_blob);
　　
　　　　　　　　when 114 then
　　
　　　　　　　　　　dbms_sql.column_value(c,i,l_bfile);
　　
　　　　　　　　　　l_anydata := ANYDATA.ConvertBFile(l_bfile);
　　
　　　　　　　　end case;
　　
　　　　　　　　insert into serialized_data (tablename,row_id,colseq,item)
　　
　　　　　　　　　　values (l_tablename,l_rowid,i,l_anydata);
　　
　　　　　　end loop;
　　
　　　　end loop;
　　
　　　　dbms_sql.close_cursor(c);
　　
　　end;
　　
　　/
　　
　　show errors;
　　
　　如果我希望对“EMP”和“DEPT”表格串行化，我可以按照以下代码通过SQL*Plus来完成：
　　
　　exec serialize('emp');
　　
　　exec serialize('dept');
　　
　　select t.item.gettypename() from serialized_data t;
　　
　　使用ANYDATA中的一个问题是，如果是对象，则只有很少的信息可以通过直接SQL恢复过来。表格数据必须使用PL/SQL过程进行访问。为了表明这点，我将回过头来对原始表格中的一栏和串行化表格中的一栏进行比较。我可以使此匿名PS/SQL代码段如下表示：
　　
　　Declare
　　
　　　　l_anydata　 anydata;
　　
　　　　l_vc2　 varchar2(32767);
　　
　　　　x　　　 pls_integer;
　　
　　begin
　　
　　　　for row in
　　
　　　　(
　　
　　　　　　select emp.ename,sd.item
　　
　　　　　　　from emp,serialized_data sd
　　
　　　　　　 where emp.rowid = sd.row_id
　　
　　　　　　　 and sd.colseq = 3
　　
　　　　　　　 and sd.tablename = 'EMP'
　　
　　　　)
　　
　　　　loop
　　
　　　　　　l_anydata := row.item;
　　
　　　　　　if l_anydata.GetVarchar2(l_vc2) = DBMS_TYPES.SUCCESS then
　　
　　　　　　　　dbms_output.put_line(row.ename||' < => '||l_vc2);
　　
　　　　　　else
　　
　　　　　　　　dbms_output.put_line('error!');
　　
　　　　　　end if;
　　
　　　　end loop;
　　
　　end;
　　
　　/
　　
　　show errors;
　　
　　SMITH < => SMITH
　　
　　ALLEN < => ALLEN
　　
　　WARD < => WARD
　　
　　JONES < => JONES
　　
　　MARTIN < => MARTIN
　　
　　BLAKE < => BLAKE
　　
　　CLARK < => CLARK
　　
　　SCOTT < => SCOTT
　　
　　KING < => KING
　　
　　TURNER < => TURNER
　　
　　ADAMS < => ADAMS
　　
　　JAMES < => JAMES
　　
　　FORD < => FORD
　　
　　MILLER < => MILLER
　　
　　PL/SQL procedure suclearcase/" target="_blank" >ccessfully completed.
　　
　　输出显示了EMP表格中的ENAME的原始值和串行化值之间的比较。

原文转自：http://www.ltesting.net